REM cls
REM @echo off
echo *** Pismo Private Folder environment starter ***
echo.
echo   Usage: %~nx0 pfopath [driveletter]
echo.

REM -- Validate if Pismo is installed
for %%i in (pfm.exe) do if "%%~$PATH:i" == "" echo Error: pfm.exe not found. & goto EOF

REM -- Get & check arguments
set pfopath=%1
set pfodrive=%2
if "%pfopath%"=="" echo Error: Pismo Private Folder path is not given. & goto EOF
if not exist %pfopath% echo Error: %pfopath% is not found. & goto EOF
if "%pfodrive%"=="" set pfodrive=P
if exist %pfodrive%:\ echo Error: Drive letter %pfodrive%: is already occupied. & goto EOF

REM -- Mount Pismo Private Folder
echo mounting %pfopath% ...
pfm mount %pfopath%
if not exist %pfopath%\ echo Error: Failed to mount %pfopath%. & goto EOF

REM -- Assign a virtual drive letter to the folder (like removable device)
subst %pfodrive%: %pfopath%
if not exist %pfodrive%:\ echo Error: Invalid drive letter %pfodrive%. & goto UNMOUNT

REM -- Open the environment
pushd %pfodrive%:\
echo starting %pfodrive%:\open.bat ...
if exist open.bat cmd /c open.bat
echo Pismo Private Folder environment started.

REM -- Wait while the environment is used
:PAUSE
set /P YN="Close this environment now? (Y/n) "
if "%YN%"=="Y" goto CLOSE
if "%YN%"=="y" goto CLOSE
if "%YN%"=="N" goto PAUSE
if "%YN%"=="n" goto PAUSE
echo Warning: Invalid character.
goto PAUSE

REM -- Close the environment
:CLOSE
echo starting %pfodrive%:\close.bat ...
if exist close.bat cmd /c close.bat
popd
subst %pfodrive%: /D

REM -- Unmount Pismo Private Folder
:UNMOUNT
echo unmounting %pfopath% ...
pfm flush %pfopath%
pfm unmount %pfopath%

:EOF